Ce programme est sous licence Creative Commons 2.0 BY-SA-NC
Description :
Salut à tous !
Aujourd'hui je ne décroche pas la Lune, mais je vous propose un petit outil que j'utilise très souvent pour créer mes graphismes rapidement en Drawstat, tout en les compressant pour en faire rentrer un maximum dans un seul File de List.
Le programme génère dans la fn 1 le paramétrage de la fenêtre graphique et en fn 2 le code à coller dans vos programmes, qui contient l'ensemble des 6 Lists de coordonnées, réunies en une seule.
Le fonctionnement est très simple, tout est expliqué directement dans le programme.
Si d'aventure il vous restait des questions, je suis à votre disposition !
Je m'y suis recollé il y a quelques semaines. Cependant, avec la découverte des chaines de caractères (le projet était initialement conçu sur G100+) et les nouvelles astuces (comme avec les listes), il y a beaucoup de chose à refaire. Et comme je suis plutôt perfectionniste, j'ai sans cesse envie de l'optimiser au maximum. Actuellement, ce n'est pas le moment pour me relancer dans un si gros proje, mais il est toujours là, dans ma fidèle Graph 85 SD.
ah un petit outil qui m'intéresse je download direct j'ai jamais le courage de faire de beaux graphismes drawstat car faut avouer que... c'est un peu soulant à faire à l'aveuglette
Pwet !
J'adorerais avoir ce programme mais le truc c'est que je n'ai plus d'ordi ces temps-ci (je suis ici sur mon portable ^^'), je ne peux donc pas obtenir cet outil qui a l'air vachement bien fait (c'est que c'est difficile de faire un branchement USB entre la calto et le téléphone... Et d'avoir une machine virtuelle de Windows sur mon phone).
Est-ce qu'une âme bien intentionnée pourrait me copier le code sur pastebin ou sauvagement ici pour que je puisse ainsi obtenir ce soft? :3
Merci d'avance,
Au revoir,
Kakemo.
Pwet kakemo dsl mais moi aussi je suis sur portable maus je voulais juste rebondir sur le projet de totoyo qui nest jamais sorti finalement comptes tu le reprendre un jour ?
Je ne connais pas l'ensemble des codes de caractères sur FA-124.
Ceux que je n'ai pas pu convertir sont généralement utilisés dans les textes et n'ont donc pas, normalement, d'influence sur le bon fonctionnement du programme.
Regarde le screenshot du programme (cf en haut de la page) pour deviner ces caractères
Code source
trop large pour le site
0->A~L:Lbl 0
ClrText
Menu "#E5BA#E5BA EasyºDrawstat #E5B9#E5B9","Aide",1,"Paramétrer",2,"Dessiner",3,"Compiler",4,"Crédits",5,"Quitter",6
Lbl 5
"#E5BA#E5BA#E5BA EasyºDrawstat #E5B9#E5B9#E5B9Création rapide de graphismes usants du Drawstat."
"#E5BA#E5BA#E5BA #E569e0#E653#E654#E656 º 2013 #E5B9#E5B9#E5B9"◢
Goto 0
Lbl 6
ClrList
""->Str 1
""->Str 2
Stop
Lbl 1
ClrText
Menu "#E5BA#E5BA#E5BA#E5BA#E5BA Aide #E5B9#E5B9#E5B9#E5B9#E5B9","Paramétrage",7,"Dessin",8,"Compilation",9,"Restrictions",R,"Retour",0
Goto 0
Lbl 7
"#E5BA#E5BA#E5BA#E5BA Paramétrage #E5B9#E5B9#E5B9#E5B9Il permet de préparerl'écran graphique et le Drawstat. Apr≠s utilisation, colle lecontenu de la fn 1."◢
Goto 1
Lbl 8
"#E5BA Commandes dessin #E5B9 [F1º2º3]: graph 1,2,3[REPLAY]: Déplacer [EXIT] : retour menu[EXE] : valider [F6] : reset"◢
Goto 1
Lbl 9
"#E5BA#E5BA#E5BA#E5BA Compilation #E5B9#E5B9#E5B9#E5B9La compilation permetde générer une seule List contenant toutesles coordonnées des 6autres."◢
"#E5BA#E5BA#E5BA#E5BA Compilation #E5B9#E5B9#E5B9#E5B9Pour obtenir cette List, il te suffit decoller le contenu de la fn 2 dans l'un de tes programmes."◢
Goto 1
Lbl R
"#E5BA#E5BA#E5BA Restrictions #E5B9#E5B9#E5B9 Le programme ne g≠re que des dessins de 20coordonnées max par Graph, et comprises entre 1 et 99"◢
Goto 1
Lbl 2
ClrText
0->A
Menu "Paramétrage","S-Gph1 ",A,"S-Gph2 ",B,"S-Gph3 ",C,"Retour",D
Lbl A:Isz A
Lbl B:Isz A
Lbl C:Isz A
4-A->A
Do
A=1=>"#E5BA Param≠tre S-Gph1 #E5B9"
A=2=>"#E5BA Param≠tre S-Gph2 #E5B9"
A=3=>"#E5BA Param≠tre S-Gph3 #E5B9"
"[0] DrawOff
[1] xyLine
[2] Scatter Square
[3] Scatter Cross
[4] Scatter Dot "?->B
LpWhile B<0 Or B>4
A=1=>B->I
A=2=>B->J
A=3=>B->K
Goto 2
Lbl D
Goto 0
Lbl 3
If Not (I+J+K
Then "#E5BA#E5BA#E5BA#E5BA#E5BA#E5BA Oubli #E5B9#E5B9#E5B9#E5B9#E5B9#E5B9"
""
" Param≠tre au moins l'un des 3 Graphs ·!·"◢
Goto 0
IfEnd
Do
For 1->A To 6
1->Dim List A
Next
BG-None
ViewWindow 1,127,0,1,63,0
Graph X≥100
StoPict 20
BG-Pict 1
K=>59->G
J=>69->G
I=>79->G
Do
If (G=79 And I≥1) Or (G=69 And J≥1) Or (G=59 And K≥1)
Then 2(8-Int (.1G->F
F-1->H
Dim List F->E
Cls
If E=1
Then Do
Plot ◢
X->A:Y->B
X->C:Y->D
C->List H[1
D->List F[1
LpWhile X≥100
Else List H[E->A:A->C
List F[E->B:B->D
IfEnd
IfEnd
Cls
(F=2 And I=1) Or (F=4 And J=1) Or (F=6 And K=1)=>F-Line A,B,C,D
(F=2 And I>1) Or (F=4 And J>1) Or (F=6 And K>1)=>PlotOn C,D
Do
Getkey->G
LpWhile Not G
G=27=>Isz C
G=38=>Dsz C
G=37=>Dsz D
G=28=>Isz D
If G=31
Then StoPict 1
1->L
C->A
D->B
C->List H[E
D->List F[E
Isz E
E=21=>47->G
IfEnd
LpWhile G≠47 And G≠29
LpWhile G≠47
BG-None:Cls
Goto 0
Lbl 4
Do
ClrText
If Not L
Then "#E5BA#E5BA#E5BA#E5BA#E5BA#E5BA Oubli #E5B9#E5B9#E5B9#E5B9#E5B9#E5B9"
""
"Il faut d'abord faire un zoli dessin ·!·"◢
Goto 0
IfEnd
" Quelle List veuxºtu utiliser (1~20) "?->L
LpWhile L<1 Or L>20
L+6->L
0->C
ClrText
Locate 6,3,"Compilation"
Locate 9,5,"#E6A5#E6A5#E6A5#E6A5#E6A5"
For 2->A To 6 Step A
Dim List A
Ans>C=>Ans->C
Next
Locate 9,5,"#E6A6"
For 2->A To 6 Step 2
Dim List A->E
While E<C
A-1->D
List D[E->List D[E+1
List A[E->List A[E+1
Isz E
WhileEnd
Next
Locate 10,5,"#E6A6"
E10List 1+E8List 2+E6List 3+E4List 4+E2List 5+List 6->List E
"BG-None
ViewWindow 1,127,0,1,63
FuncOff
AxesOff
S-WindMan
"->Str 1
"
"->Str 2
For 1->A To 3
A=1=>I->B
A=2=>J->B
A=3=>K->B
A=1=>Str 1+"S-Gph1 "->Str 1
A=2=>Str 1+"S-Gph2 "->Str 1
A=3=>Str 1+"S-Gph3 "->Str 1
Not B=>Str 1+"DrawOff"->Str 1
If B
Then Str 1+"DrawOn,"->Str 1
B=1=>Str 1+"xyLine"->Str 1
B≥2=>Str 1+"Scatter"->Str 1
A=1=>Str 1+",List 1,List 2,1,"->Str 1
A=2=>Str 1+",List 3,List 4,1,"->Str 1
A=3=>Str 1+",List 5,List 6,1,"->Str 1
B=2=>Str 1+"Square"->Str 1
B=3=>Str 1+"Cross"->Str 1
B=4 Or B=1=>Str 1+"Dot"->Str 1
IfEnd
Str 1+Str 2->Str 1
Next
Str 1->fn1
Locate 11,5,"#E6A6"
"{"->Str 2
For 1->A To Dim List E
""->Str 1
List E[A
For 1->C To 1+Intg log Ans
StrMid("0123456789",1+Int (10Frac (Ans/10^C)),1)+Str 1->Str 1
Next
Str 2+Str 1->Str 2
A≠Dim List E=>Str 2+","->Str 2
Next
Locate 12,5,"#E6A6"
""->Str 1
For 1->C To 1+Intg log L
StrMid("0123456789",1+Int (10Frac (L/10^C)),1)+Str 1->Str 1
Next
Locate 13,5,"#E6A6"
Str 2+"->List "+Str 1->fn2
Locate 6,3," Terminé ·!· "◢
Goto 0
Planète Casio est un site communautaire non affilié à Casio. Toute reproduction de Planète Casio, même partielle, est interdite.
Les programmes et autres publications présentes sur Planète Casio restent la propriété de leurs auteurs et peuvent être soumis à des licences ou copyrights.
CASIO est une marque déposée par CASIO Computer Co., Ltd
).
